Hi Bill,
If what your radar data files are like is what I imagine then
ferret's curvilinear versions of contouring and vector plots should
prove useful I imagine. Here is a demo, probably unrealistic in terms
of the data file I've constructed to allow a lat-lon chart overlay -
more a proof of concept.
! Step 1: Make a distance/angle netCDF file
def axis/x=25:1025:50/units=km dist ! distance bins in 25km steps
def axis/y/modulo/y=5:360:5/units=degrees angle ! angles in 5deg steps
! beginning 5deg north of east
def grid/x=dist/y=angle gpolar
let d2r=atan(1.)/45 ! degree to radian converter
!define a test function ...
let/title="Test Variable" v=cos(6*d2r*y[g=gpolar])/x[g=gpolar]
! ... and save it to a netcdf file
save/file=radar.nc v
! Step 2: Read in the radar data and plot it
! cancel the variables so the radar "data" can be read in
can var/all
use radar.nc
sho data
! currently SET data sets:
! 1> ./radar.nc (default)
! name title I J K L
! V Test Variable 1:21 1:72 ... ...
!define cartesian coordinates ...
let d2r=atan(1.)/45 ! degree to radian converter
let/title="x(km)" xkm=x[g=v]*cos(d2r*y[g=v])
let/title="y(km)" ykm=x[g=v]*sin(d2r*y[g=v])
! ... and contour [abs(v)]^0.25 (v itself drops off rather fast)
fill/set abs(v)^0.25,xkm,ykm
ppl axlen,6,6 ! set aspect ratio to 1:1
ppl fill
! create a gif of result - attached to this e-mail
frame/file=radar-cartesian.gif
! now do it in lat/lon coordinates
let x0=235 ; let y0=50 ; east-long & lat of radar location
let/title="Latitude" ylat=y0+ykm/111.1
let/title="East Longitude" xlon=x0+xkm/(cos(d2r*ylat)*111.1)
fill/set abs(v)^0.25,xlon,ylat
ppl axlen,6,6 ; ppl fill ! cosine latitude noticable for this super-radar
! add the coastline from the etopo5 topography file
use etopo5
region/x=220:250/y=41:60
contour/o/nolab/lev=(0.1) rose[d=2]
! and create another gif - also attached
frame/file=radar-latlon.gif
!-------------------------------------------------
Hope this is of use,
Mick
PS If your netCDF files are structured far differently than mine, I
suspect that with slightly modified algebra, it would still work.
|!!! Mick.Spillane@noaa.gov !!!|
|__Room 2070 Bldg#3 NOAA/PMEL__|
|____Phone_:_(206)526-6780_____|
On Fri, 16 Apr 2004, Bill Conway wrote:
> I have been searching far and wide for a viewer, commercial or otherwise
> that will display radar data (ie, polar radial data). Have had no luck. Does
> anyone have any ideas?
Attachment:
radar-cartesian.gif
Description: radar-cartesian.gif
Attachment:
radar-latlon.gif
Description: radar-latlon.gif
